enableFeaturePreview("VERSION_CATALOGS")

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        maven { url 'https://jitpack.io' }
        mavenCentral()
        mavenLocal()
    }

    versionCatalogs {
        libs {
            alias('nordic-ble-common').to('no.nordicsemi.android:ble-common:2.4.0-beta01')
            alias('nordic-ble-ktx').to('no.nordicsemi.android:ble-ktx:2.4.0-beta01')
            alias('nordic-log').to('no.nordicsemi.android:log:2.3.0')
            alias('nordic-scanner').to('no.nordicsemi.android.support.v18:scanner:1.6.0')
            alias('nordic-dfu').to('no.nordicsemi.android:dfu:1.12.1-beta01')

            version('commonlibraries', '1.0.1')
            alias('nordic-ui-scanner').to('no.nordicsemi.android.common', 'uiscanner').versionRef('commonlibraries')
            alias('nordic-navigation').to('no.nordicsemi.android.common', 'navigation').versionRef('commonlibraries')
            alias('nordic-theme').to('no.nordicsemi.android.common', 'theme').versionRef('commonlibraries')

            alias('localbroadcastmanager').to('androidx.localbroadcastmanager:localbroadcastmanager:1.1.0')
            alias('material').to('com.google.android.material:material:1.6.0-alpha01')

            version('lifecycle', '2.4.0')
            alias('lifecycle-activity').to('androidx.lifecycle', 'lifecycle-runtime-ktx').versionRef('lifecycle')
            alias('lifecycle-service').to('androidx.lifecycle', 'lifecycle-service').versionRef('lifecycle')

            alias('androidx-core').to('androidx.core:core-ktx:1.7.0')
            alias('compose-activity').to('androidx.activity:activity-compose:1.4.0')
            alias('compose-lifecycle').to('androidx.lifecycle:lifecycle-viewmodel-compose:2.4.0')

            version('compose', '1.0.5')
            alias('compose-livedata').to('androidx.compose.runtime', 'runtime-livedata').versionRef('compose')
            alias('compose-ui').to('androidx.compose.ui', 'ui').versionRef('compose')
            alias('compose-material').to('androidx.compose.material3:material3:1.0.0-alpha04')
            alias('compose-tooling-preview').to('androidx.compose.ui', 'ui-tooling-preview').versionRef('compose')
            alias('compose-navigation').to('androidx.navigation:navigation-compose:2.4.0-alpha09')
            bundle('compose', ['compose-livedata', 'compose-ui', 'compose-material', 'compose-tooling-preview', 'compose-navigation'])

            alias('material-icons').to('androidx.compose.material', 'material-icons-core').versionRef('compose')
            alias('material-icons-extended').to('androidx.compose.material', 'material-icons-extended').versionRef('compose')
            bundle('icons', ['material-icons', 'material-icons-extended'])

            alias('hilt-android').to('com.google.dagger:hilt-android:2.38.1')
            alias('hilt-compiler').to('com.google.dagger:hilt-compiler:2.40.4')
            alias('hilt-compose').to('androidx.hilt:hilt-navigation-compose:1.0.0-rc01')
            alias('hilt-lifecycle').to('androidx.hilt:hilt-lifecycle-viewmodel:1.0.0-alpha03')
            alias('hilt-lifecyclecompiler').to('androidx.hilt:hilt-compiler:1.0.0')
            bundle('hilt', ['hilt-android', 'hilt-compose', 'hilt-lifecycle'])
            bundle('hiltkapt', ['hilt-compiler', 'hilt-lifecyclecompiler'])

            alias('kotlin-coroutines').to('org.jetbrains.kotlinx:kotlinx-coroutines-core:1.5.2')
            alias('google-permissions').to('com.google.accompanist:accompanist-permissions:0.18.0')
            alias('chart').to('com.github.PhilJay:MPAndroidChart:v3.1.0')

            //-- Test ------------------------------------------------------------------------------
            alias('test-junit').to('junit:junit:4.13.2')
            alias('android-test-junit').to('androidx.test.ext:junit:1.1.3')
            alias('android-test-espresso').to('androidx.test.espresso:espresso-core:3.4.0')
            alias('android-test-compose-ui').to('androidx.compose.ui', 'ui-test-junit4').versionRef('compose')
            alias('android-test-compose-tooling').to('androidx.compose.ui', 'ui-tooling').versionRef('compose')

            alias('mockk-main').to('io.mockk:mockk:1.12.2')
            alias('mockk-jvm').to('io.mockk:mockk-agent-jvm:1.12.2')
            alias('test-coroutines').to('org.jetbrains.kotlinx:kotlinx-coroutines-test:1.6.0')
            bundle('test', ['test-junit', 'android-test-junit', 'mockk-main', 'mockk-jvm', 'test-coroutines'])
        }
    }
}

rootProject.name = "Android-nRF-Toolbox"

include ':app'

include ':profile_bps'
include ':profile_cgms'
include ':profile_csc'
include ':profile_dfu'
include ':profile_gls'
include ':profile_hrs'
include ':profile_hts'
include ':profile_prx'
include ':profile_rscs'
include ':profile_uart'

include ':lib_service'
include ':lib_theme'
include ':lib_utils'

if (file('../Android-Common-Libraries').exists()) {
    includeBuild('../Android-Common-Libraries')
}

if (file('../Android-BLE-Library').exists()) {
    includeBuild('../Android-BLE-Library')
}